Added CMake build rules

Signed-off-by: Mavridis Philippe <mavridisf@gmail.com>

CMakeLists.txt

@@ -0,0 +1,69 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8.12 )
+
+
+#### general package setup
+
+project( twin-style-suse2 )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckSymbolExists      )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,25 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+tde_setup_largefiles( )
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  tde_setup_gcc_visibility( )
+endif( WITH_GCC_VISIBILITY )

config.h.cmake

@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@

src/CMakeLists.txt

@@ -0,0 +1,53 @@
+tde_import( twin )
+
+add_subdirectory( config )
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIBRARY_DIRS}
+)
+
+
+##### twin3_SUSE2 (kpart)
+
+tde_add_kpart( twin3_SUSE2 AUTOMOC
+
+  SOURCES
+        SUSE2.cpp
+        SUSE2client.cpp
+        SUSE2button.cpp
+	shadow.cpp
+        misc.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdecorations-shared
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### other data
+
+install(
+    FILES SUSE2.desktop
+    DESTINATION ${DATA_INSTALL_DIR}/twin
+)
+
+install(
+    FILES titlebar_decor.png
+    DESTINATION ${DATA_INSTALL_DIR}/twin/pics
+)
+
+install(
+    FILES SUSE2.kcsrc
+    DESTINATION ${DATA_INSTALL_DIR}/tdedisplay/color-schemes
+)

src/config/CMakeLists.txt

@@ -0,0 +1,28 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIBRARY_DIRS}
+)
+
+
+##### twin_SUSE2_config (kpart)
+
+tde_add_kpart( twin_SUSE2_config AUTOMOC
+
+  SOURCES
+        config.cpp
+        configdialog.ui
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)