conversion to the cmake building system

Signed-off-by: gregory guy <g-gregory@gmx.fr>

CMakeLists.txt

@@ -0,0 +1,68 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( keximdb )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( ${PROJECT_NAME} )
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,37 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  if( NOT UNIX )
+    tde_message_fatal( "gcc visibility support was requested, but your system is not *NIX" )
+  endif( NOT UNIX )
+  set( __KDE_HAVE_GCC_VISIBILITY 1 )
+  set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+  set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+endif( WITH_GCC_VISIBILITY )
+
+
+##### Look for glib2
+
+pkg_search_module( GLIB2 glib-2.0 )
+if( NOT GLIB2_FOUND )
+    tde_message_fatal( "glib-2.0 is required, but was not found on your system" )
+endif( NOT GLIB2_FOUND )

config.h.cmake

@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@

keximdb/CMakeLists.txt

@@ -0,0 +1 @@
+add_subdirectory( src )

keximdb/src/CMakeLists.txt

@@ -0,0 +1,2 @@
+add_subdirectory( mdbtools )
+add_subdirectory( keximdb )

keximdb/src/keximdb/CMakeLists.txt

@@ -0,0 +1,40 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${CMAKE_SOURCE_DIR}/keximdb/src/mdbtools/include
+  ${GLIB2_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+add_definitions( -DMDB_NO_BACKENDS=1 -DMDB_NO_STATS=1 )
+
+
+##### keximigrate_mdb (kpart)
+
+tde_add_kpart( keximigrate_mdb AUTOMOC
+
+  SOURCES
+        mdbmigrate.cpp
+  LINK
+     tdecore-shared
+     mdb-static
+     keximigrate kexiutils kexidb
+     ${GLIB2_LIBRARIES} 
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### other data
+
+install(
+    FILES keximigrate_mdb.desktop
+    DESTINATION ${SERVICES_INSTALL_DIR}
+)

keximdb/src/mdbtools/CMakeLists.txt

@@ -0,0 +1,3 @@
+# This file is genereted by trinity-automake-cmake-convert script by Fat-Zer
+
+add_subdirectory( libmdb )

keximdb/src/mdbtools/libmdb/CMakeLists.txt

@@ -0,0 +1,38 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${CMAKE_SOURCE_DIR}/keximdb/src/mdbtools/include
+  ${GLIB2_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+add_definitions( -DMDB_NO_BACKENDS=1 -DMDB_NO_STATS=1 )
+
+
+##### mdb (static)
+
+tde_add_library( mdb STATIC_PIC AUTOMOC
+
+  SOURCES
+        catalog.c
+        mem.c
+        file.c
+        table.c
+        data.c
+        dump.c
+        money.c
+        index.c
+        write.c
+        map.c
+        options.c
+        iconv.c
+        sargs.c
+        like.c
+)