conversion to the cmake building system

Signed-off-by: gregory guy <g-gregory@gmx.fr>

CMakeLists.txt

@@ -0,0 +1,82 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( kdiff3 )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckSymbolExists      )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### user requested modules
+
+option( BUILD_ALL "Build all" ON                             )
+option( BUILD_DOC "Build documentation" ${BUILD_ALL}         )
+option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+add_subdirectory( kdiff3plugin )
+tde_conditional_add_subdirectory( BUILD_DOC man      )
+tde_conditional_add_subdirectory( BUILD_DOC doc      )
+tde_conditional_add_subdirectory( BUILD_DOC data/doc )
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po              ) 
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS kdiff3plugin/po )
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,25 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+tde_setup_largefiles( )
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  tde_setup_gcc_visibility( )
+endif( WITH_GCC_VISIBILITY )

config.h.cmake

@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@

data/doc/CMakeLists.txt

@@ -0,0 +1,6 @@
+file( GLOB _htmls RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.html )
+
+install(
+    FILES ${_htmls}
+    DESTINATION ${SHARE_INSTALL_PREFIX}/doc/${PROJECT_NAME}/html
+)

doc/CMakeLists.txt

@@ -0,0 +1 @@
+tde_auto_add_subdirectories( )

doc/da/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG da )

doc/de/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG de )

doc/en/CMakeLists.txt

@@ -0,0 +1,8 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} )
+
+file( GLOB _pngs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.png )
+
+install(
+    FILES ${_pngs}
+    DESTINATION ${SHARE_INSTALL_PREFIX}/doc/${PROJECT_NAME}/html
+)

doc/es/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG es )

doc/et/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG et )

doc/fr/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG fr )

doc/it/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG it )

doc/nl/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG nl )

doc/pt/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG pt )

doc/sv/CMakeLists.txt

@@ -0,0 +1 @@
+tde_create_handbook( DESTINATION ${PROJECT_NAME} LANG sv )

kdiff3plugin/CMakeLists.txt

@@ -0,0 +1,40 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### libkdiff3plugin (kpart)
+
+tde_add_kpart( libkdiff3plugin AUTOMOC
+
+  SOURCES
+        kdiff3plugin.cpp
+  LINK
+     konq
+     tdecore-shared
+     tdeui-shared
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### other data
+
+install(
+    FILES kdiff3_plugin.desktop
+    DESTINATION ${SERVICES_INSTALL_DIR}
+)
+
+install(
+    FILES kdiff3plugin.desktop
+    DESTINATION ${APPS_INSTALL_DIR}/.hidden
+)

kdiff3plugin/po/CMakeLists.txt

@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+    tde_create_translation( LANG auto OUTPUT_NAME kdiff3_plugin )
+endif( )

man/CMakeLists.txt

@@ -0,0 +1,5 @@
+INSTALL(
+    FILES ${PROJECT_NAME}.1
+    DESTINATION ${MAN_INSTALL_DIR}/man1
+    COMPONENT doc
+)

po/CMakeLists.txt

@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+    tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )
+endif( )

src/CMakeLists.txt

@@ -0,0 +1,88 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### kdiff3 (executable)
+
+tde_add_executable( ${PROJECT_NAME} AUTOMOC
+
+  SOURCES
+        main.cpp
+        kdiff3_shell.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+     tdeparts-shared
+
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+
+##### libkdiff3part (kpart)
+
+tde_add_kpart( libkdiff3part AUTOMOC
+
+  SOURCES
+        kdiff3_part.cpp
+        kdiff3.cpp
+        directorymergewindow.cpp
+        merger.cpp
+        pdiff.cpp
+        difftextwindow.cpp
+        diff.cpp
+        optiondialog.cpp
+        mergeresultwindow.cpp
+        fileaccess.cpp
+        gnudiff_analyze.cpp
+        gnudiff_io.cpp
+        gnudiff_xmalloc.cpp
+        common.cpp
+        smalldialogs.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+     tdeprint-shared
+     tdeparts-shared
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### icons
+
+tde_install_icons( ${PROJECT_NAME} )
+
+
+##### other data
+
+install(
+    FILES kdiff3_shell.rc
+    DESTINATION ${DATA_INSTALL_DIR}/${PROJECT_NAME}
+)
+
+install(
+    FILES kdiff3part.desktop
+    DESTINATION ${SERVICES_INSTALL_DIR}
+)
+
+install(
+    FILES kdiff3_part.rc
+    DESTINATION ${DATA_INSTALL_DIR}/kdiff3part
+)
+
+install(
+    FILES ${PROJECT_NAME}.desktop
+    DESTINATION ${XDG_APPS_INSTALL_DIR}
+)

src/kdiff3_part.cpp

@@ -296,7 +296,7 @@ TDEInstance* KDiff3PartFactory::instance()
 }
 
 extern "C"
-{
+{ KDE_EXPORT
     void* init_libkdiff3part()
     {
         return new KDiff3PartFactory;