conversion to the cmake building system

Signed-off-by: gregory guy <g-gregory@gmx.fr>

CMakeLists.txt

@@ -0,0 +1,83 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( kcmldapmanager )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckSymbolExists      )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### user requested modules
+
+option( BUILD_ALL "Build all" ON                             )
+option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
+
+
+##### user defined options #######
+
+set( KDE_CONFDIR "/etc/trinity" CACHE STRING "Path for the config system" )
+set( AVAILABLE_SHELLS /bin/bash /bin/sh /bin/dash /bin/rbash /usr/bin/screen CACHE STRING "Available shells" )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src     )
+add_subdirectory( cmdline )
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po ) 
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,76 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+tde_setup_largefiles( )
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  tde_setup_gcc_visibility( )
+endif( WITH_GCC_VISIBILITY )
+
+
+##### check for ldap
+
+find_library( HAVE_LIBLDAP ldap )
+if( HAVE_LIBLDAP )
+   set( LDAP_LIBRARIES "ldap" )
+  else()
+   tde_message_fatal( "ldap is required, but was not found on your system" )
+endif( HAVE_LIBLDAP )
+
+
+##### check for tdeldap
+
+find_library( HAVE_LIBTDELDAP tdeldap )
+if( HAVE_LIBTDELDAP )
+   set( TDELDAP_LIBRARIES "tdeldap" )
+  else()
+   tde_message_fatal( "libtdeldap is required, but was not found on your system" )
+endif( )
+
+
+##### check for krb5
+
+pkg_search_module( KRB5 heimdal-krb5 krb5 )
+if( NOT KRB5_FOUND)
+  if( NOT DEFINED KRB5_CONFIG_EXECUTABLE )
+    find_program( KRB5_CONFIG_EXECUTABLE NAMES krb5-config.heimdal krb5-config )
+    if( NOT KRB5_CONFIG_EXECUTABLE )
+      tde_message_fatal( "krb5 library is required but not found on your system" )
+    endif( )
+  endif( )
+
+  execute_process(
+    COMMAND ${KRB5_CONFIG_EXECUTABLE} --libs
+    OUTPUT_VARIABLE KRB5_LIBRARIES
+    ERROR_VARIABLE KRB5_LIBRARIES
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    ERROR_STRIP_TRAILING_WHITESPACE
+  )
+  execute_process(
+    COMMAND ${KRB5_CONFIG_EXECUTABLE} --cflags
+    OUTPUT_VARIABLE KRB5_INCLUDE_DIRS
+    ERROR_VARIABLE KRB5_INCLUDE_DIRS
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    ERROR_STRIP_TRAILING_WHITESPACE
+  )
+  if( NOT "${KRB5_LIBRARIES}" STREQUAL "" )
+    set( KRB5_FOUND 1 )
+  endif( )
+endif( )

cmdline/CMakeLists.txt

@@ -0,0 +1,31 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TDE_INCLUDE_DIR}/tde
+  ${KRB5_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### tdeldapmanager (executable)
+
+tde_add_executable( tdeldapmanager AUTOMOC
+
+  SOURCES
+        main.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+     ${TDELDAP_LIBRARIES}
+     ${KRB5_LIBRARIES}
+
+  DESTINATION ${BIN_INSTALL_DIR}
+)

cmdline/main.cpp

@@ -38,9 +38,9 @@
 
 #include <libtdeldap.h>
 
-// FIXME
+#ifndef KDE_CONFDIR
-// Connect this to CMake/Automake
 #define KDE_CONFDIR "/etc/trinity"
+#endif
 
 static const char description[] =
 	I18N_NOOP("TDE utility for managing a Kerberos realm");

config.h.cmake

@@ -0,0 +1,14 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@
+
+/* Path for the config system */
+#cmakedefine KDE_CONFDIR "@KDE_CONFDIR@"
+
+/* Available shells */
+#cmakedefine AVAILABLE_SHELLS "@AVAILABLE_SHELLS@"

po/CMakeLists.txt

@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+    tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )
+endif( )

src/CMakeLists.txt

@@ -0,0 +1,48 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TDE_INCLUDE_DIR}/tde
+  ${KRB5_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### kcm_ldapmanager (kpart)
+
+tde_add_kpart( kcm_ldapmanager AUTOMOC
+
+  SOURCES
+        ldapconfigbase.ui
+        userconfigbase.ui
+        groupconfigbase.ui
+        machineconfigbase.ui
+        serviceconfigbase.ui
+        ldapmgr.cpp
+        userconfigdlg.cpp
+        groupconfigdlg.cpp
+        machineconfigdlg.cpp
+        serviceconfigdlg.cpp
+  LINK
+     tdeio-shared
+     tdeui-shared
+     ${LDAP_LIBRARIES}
+     ${TDELDAP_LIBRARIES}
+     ${KRB5_LIBRARIES}
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### other data
+
+install(
+    FILES ldapmanager.desktop
+    DESTINATION ${XDG_APPS_INSTALL_DIR}
+)

src/groupconfigdlg.h

@@ -23,7 +23,7 @@
 
 #include <kdialogbase.h>
 
-#include "libtdeldap.h"
+#include <libtdeldap.h>
 #include "groupconfigbase.h"
 
 class GroupConfigDialog : public KDialogBase

src/ldapmgr.cpp

@@ -44,16 +44,16 @@
 
 #include "ldapmgr.h"
 
-#include "libtdeldap.h"
+#include <libtdeldap.h>
-#include "ldappasswddlg.h"
+#include <ldappasswddlg.h>
 #include "userconfigdlg.h"
 #include "groupconfigdlg.h"
 #include "machineconfigdlg.h"
 #include "serviceconfigdlg.h"
 
-// FIXME
+#ifndef KDE_CONFDIR
-// Connect this to CMake/Automake
 #define KDE_CONFDIR "/etc/trinity"
+#endif
 
 typedef KGenericFactory<LDAPConfig, TQWidget> LDAPConfigFactory;
 
@@ -921,3 +921,5 @@ TQString LDAPConfig::quickHelp() const
 {
 	return i18n("This module manages users, groups, and machines in LDAP realms.");
 }
+
+#include "ldapmgr.moc"

src/ldapmgr.h

@@ -30,7 +30,7 @@
 #include <tqpushbutton.h>
 #include <tqcombobox.h>
 
-#include "libtdeldap.h"
+#include <libtdeldap.h>
 #include "ldapconfigbase.h"
 
 class KSimpleConfig;

src/machineconfigdlg.h

@@ -23,7 +23,7 @@
 
 #include <kdialogbase.h>
 
-#include "libtdeldap.h"
+#include <libtdeldap.h>
 #include "machineconfigbase.h"
 
 class MachineConfigDialog : public KDialogBase

src/serviceconfigdlg.h

@@ -23,7 +23,7 @@
 
 #include <kdialogbase.h>
 
-#include "libtdeldap.h"
+#include <libtdeldap.h>
 #include "serviceconfigbase.h"
 
 class ServiceConfigDialog : public KDialogBase

src/userconfigdlg.h

@@ -23,10 +23,12 @@
 
 #include <kdialogbase.h>
 
-#include "libtdeldap.h"
+#include <libtdeldap.h>
 #include "userconfigbase.h"
 
+#ifndef AVAILABLE_SHELLS
 #define AVAILABLE_SHELLS "/bin/bash /bin/sh /bin/dash /bin/rbash /usr/bin/screen"
+#endif
 
 class UserConfigDialog : public KDialogBase
 {