[applications/amarok] initial cmake support

git-svn-id: svn://anonsvn.kde.org/home/kde/branches/trinity/applications/amarok@1214485 283d02a7-25f6-0310-bc7c-ecb5cbfe19da

CMakeLists.txt

@@ -1,51 +1,75 @@
-project(extragear-multimedia)
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
 
-set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake/modules )
+cmake_minimum_required( VERSION 2.6 )
 
-# search packages used by KDE
-find_package(KDE4 REQUIRED)
-include (KDE4Defaults)
-include (MacroLibrary)
-include(MacroOptionalAddSubdirectory)
-find_package(RUBY)
-find_package(KdeMultimedia)
-find_package(OpenGL)
-find_package(Xine)
-# are these two really required ?
-if (APPLE)
-   find_package(Carbon REQUIRED)
-endif (APPLE)
-set(TAGLIB_MIN_VERSION "1.5")
-find_package(Taglib)
 
-#amarok needs to be before add_definitions, since it builds
+##### general package setup #####################
-#some qt-only software
-if(TAGLIB_FOUND AND RUBY_EXECUTABLE AND RUBY_INCLUDE_PATH)
-   macro_optional_add_subdirectory(amarok)
-endif(TAGLIB_FOUND AND RUBY_EXECUTABLE AND RUBY_INCLUDE_PATH)
 
+project( amarok )
 
-add_definitions (${QT_DEFINITIONS} ${KDE4_DEFINITIONS})
 
-include_directories (${CMAKE_SOURCE_DIR} ${CMAKE_BINARY_DIR} ${KDE4_INCLUDES})
+##### include essential cmake modules ###########
+
+include( CheckCXXSourceCompiles )
+include( CheckFunctionExists )
+include( CheckIncludeFileCXX )
+include( CheckStructHasMember )
+include( CheckSymbolExists )
+include( CheckTypeSize )
+include( FindPkgConfig )
+
+
+##### include our cmake modules #################
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths #######################
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff ############################
+
+option( WITH_LIBVISUAL "Enable libvisual support" OFF )
+option( WITH_KONQSIDEBAR "Enable konqsidebar plugin" OFF )
+option( WITH_XINE "Enable xine-engine support" OFF )
+option( WITH_LIBGPOD "Enable iPod support from libgpod" OFF )
+
+
+##### configure checks ##########################
 
 include( ConfigureChecks.cmake )
 
-if(TAGLIB_FOUND)
-include_directories (${TAGLIB_INCLUDES})
-endif(TAGLIB_FOUND)
 
-if(KDEMULTIMEDIA_FOUND)
+###### global compiler settings #################
-   macro_optional_add_subdirectory(k3b)
+
-   macro_optional_add_subdirectory(kaudiocreator)
+add_definitions(
-endif(KDEMULTIMEDIA_FOUND)
+  -DHAVE_CONFIG_H
-macro_optional_add_subdirectory(kaffeine)
+  ${TQT_CFLAGS_OTHER}
-macro_optional_add_subdirectory(kmid)
+)
-macro_optional_add_subdirectory(kplayer)
+
-macro_optional_add_subdirectory(kmplayer)
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include tqt.h" )
-macro_optional_add_subdirectory(doc)
+set( CMAKE_SHARED_LINKER_FLAGS "-Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "-Wl,--no-undefined" )
+
+
+##### source directories ########################
+
+add_subdirectory( amarok )
+
 
-if(QT_QTOPENGL_FOUND AND OPENGL_FOUND AND XINE_FOUND)
+##### write configure files #####################
-   macro_optional_add_subdirectory(kaffeinegl)
-endif(QT_QTOPENGL_FOUND AND OPENGL_FOUND AND XINE_FOUND)
 
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -1,34 +1,139 @@
-include(CheckIncludeFile)
+#################################################
-include(CheckIncludeFiles)
+#
-include(CheckSymbolExists)
+#  (C) 2010 Serghei Amelian
-include(CheckFunctionExists)
+#  serghei (DOT) amelian (AT) gmail.com
-include(CheckLibraryExists)
+#
-include(CheckPrototypeExists)
+#  Improvements and feedback are welcome
-include(CheckTypeSize)
+#
-include(MacroBoolTo01)
+#  This file is released under GPL >= 2
-
+#
-# The FindKDE4.cmake module sets _KDE4_PLATFORM_DEFINITIONS with
+#################################################
-# definitions like _GNU_SOURCE that are needed on each platform.
+
-set(CMAKE_REQUIRED_DEFINITIONS ${_KDE4_PLATFORM_DEFINITIONS})
+check_type_size( "int" SIZEOF_INT BUILTIN_TYPES_ONLY )
-
+check_type_size( "long" SIZEOF_LONG BUILTIN_TYPES_ONLY )
-#check for libz using the cmake supplied FindZLIB.cmake
+
-macro_bool_to_01(ZLIB_FOUND HAVE_LIBZ)
+check_include_file( stdint.h HAVE_STDINT_H )
-macro_bool_to_01(JPEG_FOUND HAVE_LIBJPEG)
+check_include_file( systems.h HAVE_SYSTEMS_H )
-macro_bool_to_01(PNG_FOUND HAVE_LIBPNG)
+check_include_file( linux/inotify.h HAVE_INOTIFY )
-macro_bool_to_01(CARBON_FOUND HAVE_CARBON)
+
-macro_bool_to_01(NJB_FOUND HAVE_LIBNJB)
+check_function_exists( statvfs HAVE_STATVFS )
-macro_bool_to_01(IFP_FOUND HAVE_IFP)
+
-macro_bool_to_01(LIBVISUAL_FOUND HAVE_LIBVISUAL)
+
-macro_bool_to_01(MTP_FOUND HAVE_MTP)
+# fabsf
-
+tde_save( CMAKE_REQUIRED_LIBRARIES )
-#now check for dlfcn.h using the cmake supplied CHECK_include_FILE() macro
+set( CMAKE_REQUIRED_LIBRARIES m )
-# If definitions like -D_GNU_SOURCE are needed for these checks they
+check_function_exists( fabsf HAVE_FABSF )
-# should be added to _KDE4_PLATFORM_DEFINITIONS when it is originally
+tde_restore( CMAKE_REQUIRED_LIBRARIES )
-# defined outside this file.  Here we include these definitions in
+
-# CMAKE_REQUIRED_DEFINITIONS so they will be included in the build of
+
-# checks below.
+# taglib
-set(CMAKE_REQUIRED_DEFINITIONS ${_KDE4_PLATFORM_DEFINITIONS})
+pkg_search_module( TAGLIB taglib )
-if (WIN32)
+if( TAGLIB_FOUND )
-   set(CMAKE_REQUIRED_LIBRARIES ${KDEWIN32_LIBRARIES} )
+  if( ${TAGLIB_VERSION} VERSION_LESS "1.5" )
-   set(CMAKE_REQUIRED_INCLUDES  ${KDEWIN32_INCLUDES} )
+    tde_message_fatal( "taglib version must be at least 1.5" )
-endif (WIN32)
+  else( )
+    set( TAGLIB_15 1 )
+  endif( )
+else( )
+  tde_message_fatal( "taglib are required, but not found on your system" )
+endif( )
+
+
+# sqlite3
+pkg_search_module( SQLITE sqlite3 )
+if( NOT SQLITE_FOUND )
+  tde_message_fatal( "sqlite3 are required, but not found on your system" )
+endif( )
+
+
+# libvisual
+if( WITH_LIBVISUAL )
+
+  pkg_search_module( SDL sdl )
+  if( NOT SDL_FOUND )
+    tde_message_fatal( "SDL are required, but not found on your system" )
+  endif( )
+
+  pkg_search_module( LIBVISUAL libvisual-0.4 )
+  if( LIBVISUAL_FOUND )
+    if( ${LIBVISUAL_VERSION} VERSION_LESS "0.4.0" )
+      tde_message_fatal( "libvisual version must be at least 0.4.0" )
+    endif( )
+  else( )
+    tde_message_fatal( "libvisual are requested, but not found on your system" )
+  endif( )
+  set( HAVE_LIBVISUAL 1 )
+
+endif( )
+
+
+# xine-engine
+if( WITH_XINE )
+  pkg_search_module( XINE libxine )
+  if( XINE_FOUND )
+    if( ${XINE_VERSION} VERSION_LESS "1.0.2" )
+      tde_message_fatal( "your xine version is too old; at least 1.0.2 is required" )
+    endif( )
+  else( )
+    tde_message_fatal( "xine are requested, but not found on your system" )
+  endif( )
+endif( )
+
+
+# iPod
+if( WITH_LIBGPOD )
+
+  tde_message_fatal( "iPod support is outdated, cannot be compiled against newer libgpod" )
+
+  pkg_search_module( LIBGPOD libgpod-1.0 )
+  if( LIBGPOD_FOUND )
+    if( ${LIBGPOD_VERSION} VERSION_LESS "0.4.2" )
+      tde_message_fatal( "your libgpod version is too old; at least 0.4.2 is required" )
+    elseif( NOT ${LIBGPOD_VERSION} VERSION_LESS "0.6.0" )
+      set( HAVE_LIBGPOD_060 1 )
+    endif( )
+  else( )
+    tde_message_fatal( "libgpod-1.0 are requested, but not found on your system" )
+  endif( )
+
+  tde_save( CMAKE_REQUIRED_INCLUDES )
+  set( CMAKE_REQUIRED_INCLUDES ${LIBGPOD_INCLUDE_DIRS} )
+  check_struct_has_member( "struct _Itdb_Track" mediatype "gpod/itdb.h" HAVE_ITDB_MEDIATYPE )
+  tde_restore( CMAKE_REQUIRED_INCLUDES )
+
+endif( )
+
+
+# common required stuff
+find_package( Qt )
+find_package( TQt )
+find_package( TDE )
+
+
+# check for Qt with OpenGL support
+tde_save( CMAKE_REQUIRED_INCLUDES CMAKE_REQUIRED_LIBRARIES )
+set( CMAKE_REQUIRED_INCLUDES ${QT_INCLUDE_DIRS} )
+set( CMAKE_REQUIRED_LIBRARIES -L${QT_LIBRARY_DIRS} ${QT_LIBRARIES} )
+check_cxx_source_compiles("
+  #include <qgl.h>
+  int main(int, char**) { (void)new QGLWidget((QWidget*)0, \"qgl\"); return 0; } "
+  HAVE_QGLWIDGET )
+tde_restore( CMAKE_REQUIRED_INCLUDES CMAKE_REQUIRED_LIBRARIES )
+
+
+# konqsidebarplugin.h
+if( WITH_KONQSIDEBAR )
+  tde_save( CMAKE_REQUIRED_DEFINITIONS CMAKE_REQUIRED_INCLUDES CMAKE_REQUIRED_LIBRARIES CMAKE_REQUIRED_LIBRARIES )
+  set( CMAKE_REQUIRED_DEFINITIONS ${TQT_CFLAGS_OTHER} )
+  set( CMAKE_REQUIRED_INCLUDES ${TDE_INCLUDE_DIR};${TQT_INCLUDE_DIRS} )
+  set( CMAKE_REQUIRED_FLAGS "-include tqt.h" )
+  set( CMAKE_REQUIRED_LIBRARIES -L${QT_LIBRARY_DIRS} ${QT_LIBRARIES} )
+  check_cxx_source_compiles("
+    #include <konqsidebarplugin.h>
+    int main(int, char**) { return 0; } "
+    HAVE_KONQSIDEBARPLUGIN_H )
+  tde_restore( CMAKE_REQUIRED_DEFINITIONS CMAKE_REQUIRED_INCLUDES CMAKE_REQUIRED_LIBRARIES CMAKE_REQUIRED_LIBRARIES )
+  if( NOT HAVE_KONQSIDEBARPLUGIN_H )
+    tde_message_fatal( "konqsidebarplugin.h are requested, but not found on your system" )
+  endif( )
+endif( )

amarok/CMakeLists.txt

@@ -0,0 +1,12 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( src )

amarok/src/CMakeLists.txt

@@ -0,0 +1,110 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( amarokcore )
+add_subdirectory( magnatunebrowser )
+add_subdirectory( analyzers )
+add_subdirectory( data )
+add_subdirectory( plugin )
+add_subdirectory( images )
+add_subdirectory( loader )
+add_subdirectory( scripts )
+add_subdirectory( themes )
+add_subdirectory( vis )
+add_subdirectory( metadata )
+tde_conditional_add_subdirectory( WITH_KONQSIDEBAR konquisidebar )
+add_subdirectory( statusbar )
+add_subdirectory( engine )
+add_subdirectory( mediadevice )
+add_subdirectory( device )
+add_subdirectory( collectionscanner )
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src/amarokcore
+  ${CMAKE_BINARY_DIR}/amarok/src/magnatunebrowser
+  ${CMAKE_SOURCE_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src/analyzers
+  ${CMAKE_SOURCE_DIR}/amarok/src/statusbar
+  ${CMAKE_SOURCE_DIR}/amarok/src/plugin
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TAGLIB_INCLUDE_DIRS}
+  ${SQLITE_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+tde_install_icons( )
+install( PROGRAMS amarok_proxy.rb DESTINATION ${BIN_INSTALL_DIR} )
+install( FILES amarokui.rc DESTINATION ${DATA_INSTALL_DIR}/amarok )
+install( FILES amarokrc DESTINATION ${CONFIG_INSTALL_DIR} )
+install( FILES amarok.desktop DESTINATION ${XDG_APPS_INSTALL_DIR} )
+install( FILES amarok_plugin.desktop amarok_codecinstall.desktop DESTINATION ${SERVICETYPES_INSTALL_DIR} )
+install( FILES amarok_addaspodcast.desktop amarok_append.desktop amarok_play_audiocd.desktop DESTINATION ${DATA_INSTALL_DIR}/konqueror/servicemenus )
+install( FILES amarok.profile.xml DESTINATION ${DATA_INSTALL_DIR}/profiles )
+install( FILES amarokitpc.protocol amaroklastfm.protocol amarokpcast.protocol DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### amarokapp (executable) ####################
+
+tde_add_executable( amarokapp
+  SOURCES main.cpp
+  LINK amarok-shared
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+
+##### amarok (shared) ###########################
+
+tde_add_library( amarok SHARED AUTOMOC
+  SOURCES
+    Options1.ui Options1.ui.h Options2.ui Options4.ui Options5.ui
+    Options7.ui Options8.ui actionclasses.cpp app.cpp atomicstring.cpp
+    atomicurl.cpp browserbar.cpp clicklineedit.cpp collectionbrowser.cpp
+    collectiondb.cpp columnlist.cpp configdialog.cpp contextbrowser.cpp
+    coverfetcher.cpp covermanager.cpp cuefile.cpp dbsetup.ui dbsetup.ui.h
+    deletedialog.cpp deletedialogbase.ui deviceconfiguredialog.cpp
+    devicemanager.cpp directorylist.cpp dynamicmode.cpp enginebase.cpp
+    enginecontroller.cpp engineobserver.cpp equalizergraph.cpp
+    equalizerpresetmanager.cpp equalizersetup.cpp expression.cpp fht.cpp
+    filebrowser.cpp firstrunwizard.ui hintlineedit.cpp htmlview.cpp
+    iconloader.cpp k3bexporter.cpp kbookmarkhandler.cpp ktrm.cpp
+    lastfm.cpp mediabrowser.cpp mediadevicemanager.cpp medium.cpp
+    mediumpluginmanager.cpp metabundle.cpp metabundlesaver.cpp moodbar.cpp
+    mountpointmanager.cpp multitabbar.cpp mydiroperator.cpp newdynamic.ui
+    organizecollectiondialog.ui osd.cpp pixmapviewer.cpp playerwindow.cpp
+    playlist.cpp playlistbrowser.cpp playlistbrowseritem.cpp playlistitem.cpp
+    playlistloader.cpp playlistselection.cpp playlistwindow.cpp
+    pluginmanager.cpp podcastsettings.cpp podcastsettingsbase.ui
+    prettypopupmenu.cpp queuemanager.cpp refreshimages.cpp
+    scancontroller.cpp scriptmanager.cpp scriptmanagerbase.ui
+    scrobbler.cpp sliderwidget.cpp smartplaylisteditor.cpp socketserver.cpp
+    starmanager.cpp statistics.cpp systray.cpp tagdialog.cpp tagdialogbase.ui
+    tagguesser.cpp tagguesserconfigdialog.ui threadmanager.cpp tooltip.cpp
+    trackpickerdialog.cpp trackpickerdialogbase.ui tracktooltip.cpp
+    transferdialog.cpp xmlloader.cpp xspfplaylist.cpp editfilterdialog.cpp
+  VERSION 0.0.0
+  EMBED
+    amarokcore-static magnatunebrowser-static analyzers-static plugin-static
+    metadata-static statusbar-static
+  LINK
+    khtml-shared knewstuff-shared
+    GL ${TAGLIB_LIBRARIES} ${SQLITE_LIBRARIES} pthread
+  DESTINATION ${LIB_INSTALL_DIR}
+)

amarok/src/amarokcore/CMakeLists.txt

@@ -0,0 +1,35 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${CMAKE_SOURCE_DIR}/amarok/src/statusbar
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TAGLIB_INCLUDE_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok.kcfg DESTINATION ${KCFG_INSTALL_DIR} )
+
+
+##### amarokcore (static) #######################
+
+tde_add_library( amarokcore STATIC_PIC AUTOMOC
+  SOURCES
+    amarokdcopiface.skel amarokdcophandler.cpp
+    amarokconfig.kcfgc crashhandler.cpp
+)

amarok/src/analyzers/CMakeLists.txt

@@ -0,0 +1,31 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src
+  ${CMAKE_BINARY_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### analyzers (static) ########################
+
+tde_add_library( analyzers STATIC_PIC AUTOMOC
+  SOURCES
+    analyzerbase.cpp analyzerfactory.cpp baranalyzer.cpp
+    blockanalyzer.cpp glanalyzer.cpp glanalyzer2.cpp
+    glanalyzer3.cpp sonogram.cpp turbine.cpp boomanalyzer.cpp
+  DEPENDENCIES amarokcore-static
+)

amarok/src/collectionscanner/CMakeLists.txt

@@ -0,0 +1,33 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### amarokcollectionscanner (executable) ######
+
+tde_add_executable( amarokcollectionscanner AUTOMOC
+  SOURCES
+    main.cpp collectionscannerdcopiface.skel
+    collectionscannerdcophandler.cpp collectionscanner.cpp
+  LINK amarok-shared
+  DESTINATION ${BIN_INSTALL_DIR}
+)

amarok/src/data/CMakeLists.txt

@@ -0,0 +1,16 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES
+    Cool-Streams.xml Amarok_1.4_Welcome.ogg ball.png
+    dot.png equalizer_presets.xml firstrun.m3u
+    grid.png wirl1.png wirl2.png magnatune_logo.png
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/data )

amarok/src/device/CMakeLists.txt

@@ -0,0 +1,14 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( massstorage )
+add_subdirectory( nfs )
+add_subdirectory( smb )

amarok/src/device/massstorage/CMakeLists.txt

@@ -0,0 +1,36 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok_massstorage-device.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### libamarok_massstorage-device (module) #####
+
+tde_add_kpart( libamarok_massstorage-device
+  SOURCES
+    massstoragedevicehandler.cpp
+  LINK amarok-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/device/nfs/CMakeLists.txt

@@ -0,0 +1,35 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok_nfs-device.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### libamarok_nfs-device (module) #############
+
+tde_add_kpart( libamarok_nfs-device
+  SOURCES nfsdevicehandler.cpp
+  LINK amarok-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/device/smb/CMakeLists.txt

@@ -0,0 +1,35 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok_smb-device.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### libamarok_smb-device (module) #############
+
+tde_add_kpart( libamarok_smb-device
+  SOURCES smbdevicehandler.cpp
+  LINK amarok-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/engine/CMakeLists.txt

@@ -0,0 +1,15 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+# FIXME: we need to port other engines either
+
+add_subdirectory( void )
+tde_conditional_add_subdirectory( WITH_XINE xine )

amarok/src/engine/void/CMakeLists.txt

@@ -0,0 +1,35 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok_void-engine_plugin.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### libamarok_void-engine_plugin (module) #####
+
+tde_add_kpart( libamarok_void-engine_plugin
+  SOURCES void-engine.cpp
+  LINK amarok-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/engine/xine/CMakeLists.txt

@@ -0,0 +1,42 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${CMAKE_SOURCE_DIR}/amarok/src/amarokcore
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${XINE_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok_xine-engine.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
+install( FILES xinecfg.kcfg DESTINATION ${KCFG_INSTALL_DIR} )
+
+
+##### libamarok_xine-engine (module) ############
+
+tde_add_kpart( libamarok_xine-engine AUTOMOC
+  SOURCES
+    xine-scope.c xinecfg.kcfgc xine-engine.cpp
+    xineconfigbase.ui xine-config.cpp
+  LINK amarok-shared ${XINE_LIBRARIES}
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/images/CMakeLists.txt

@@ -0,0 +1,27 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( icons )
+
+install( FILES
+    amarok_cut.png amarok_rocks.jpg b_next.png b_pause.png b_play.png
+    b_prev.png b_stop.png back_stars_grey.png currenttrack_bar_left.png
+    currenttrack_bar_mid.png currenttrack_bar_right.png currenttrack_play.png
+    currenttrack_pause.png currenttrack_stop.png currenttrack_stop_small.png
+    currenttrack_repeat.png currenttrack_repeat_small.png
+    eq_active2.png eq_inactive2.png lastfm.png loading1.png loading2.png
+    menu_sidepixmap.png more_albums.png musicbrainz.png nocover.png
+    pl_active2.png pl_inactive2.png shadow_albumcover.png sbinner_stars.png
+    smallstar.png splash_screen.jpg star.png time_minus.png time_plus.png
+    vol_speaker.png volumeslider-gradient.png volumeslider-handle.png
+    volumeslider-handle_glow.png volumeslider-inset.png wizard_compact.png
+    wizard_xmms.png xine_logo.png
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/images )

amarok/src/images/icons/CMakeLists.txt

@@ -0,0 +1,12 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+tde_install_icons( DESTINATION ${DATA_INSTALL_DIR}/amarok/icons )

amarok/src/konquisidebar/CMakeLists.txt

@@ -0,0 +1,40 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+tde_import( konqueror )
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok.desktop DESTINATION ${DATA_INSTALL_DIR}/konqsidebartng/add )
+install( FILES amarok.desktop DESTINATION ${DATA_INSTALL_DIR}/konqsidebartng/kicker_entries )
+install( FILES amarok.desktop DESTINATION ${DATA_INSTALL_DIR}/konqsidebartng/entries )
+
+
+##### konqsidebar_universalamarok (module) ######
+
+tde_add_kpart( konqsidebar_universalamarok AUTOMOC
+  SOURCES
+    universalamarok.cpp
+    ${CMAKE_SOURCE_DIR}/amarok/src/amarokcore/amarokdcopiface.stub
+  LINK konqsidebarplugin-shared khtml-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/loader/CMakeLists.txt

@@ -0,0 +1,28 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### amarok (executable) #######################
+
+tde_add_executable( amarok
+  SOURCES loader.cpp
+  LINK kdeui-shared
+  DESTINATION ${BIN_INSTALL_DIR}
+)

amarok/src/magnatunebrowser/CMakeLists.txt

@@ -0,0 +1,36 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${CMAKE_SOURCE_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src/statusbar
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### magnatunebrowser (static) #################
+
+tde_add_library( magnatunebrowser STATIC_PIC AUTOMOC
+  SOURCES
+    magnatuneartistinfobox.cpp magnatunebrowser.cpp
+    magnatunedownloaddialogbase.ui magnatunedownloaddialog.cpp
+    magnatunepurchasedialogbase.ui magnatunepurchasedialog.cpp
+    magnatunepurchasehandler.cpp magnatunetypes.cpp magnatunexmlparser.cpp
+    magnatunedatabasehandler.cpp magnatunelistviewitems.cpp
+    magnatunelistview.cpp magnatuneredownloaddialog.cpp
+    magnatuneredownloadhandler.cpp magnatunedownloadinfo.cpp
+    magnatunealbumdownloader.cpp magnatuneredownloaddialogbase.ui
+)

amarok/src/mediadevice/CMakeLists.txt

@@ -0,0 +1,20 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+# FIXME optional devices are not ported yet
+
+add_subdirectory( generic )
+tde_conditional_add_subdirectory( WITH_LIBGPOD ipod )
+tde_conditional_add_subdirectory( WITH_IFP ifp )
+tde_conditional_add_subdirectory( WITH_LIBNJB njb )
+tde_conditional_add_subdirectory( WITH_LIBMTP mtp )
+tde_conditional_add_subdirectory( WITH_LIBKARMA riokarma )
+tde_conditional_add_subdirectory( WITH_DAAP daap )

amarok/src/mediadevice/generic/CMakeLists.txt

@@ -0,0 +1,42 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${CMAKE_SOURCE_DIR}/amarok/src/amarokcore
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES amarok_generic-mediadevice.desktop DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### libamarok_generic-mediadevice (module) ####
+
+tde_add_kpart( libamarok_generic-mediadevice AUTOMOC
+  SOURCES
+    genericmediadeviceconfigdialog.ui
+    genericmediadevice.cpp
+  LINK amarok-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+  DEPENDENCIES amarokcore-static
+)

amarok/src/mediadevice/ipod/CMakeLists.txt

@@ -0,0 +1,42 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  #${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  #${CMAKE_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${LIBGPOD_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### other data ################################
+
+install( FILES
+    amarok_ipod-mediadevice.desktop
+  DESTINATION ${SERVICES_INSTALL_DIR} )
+
+
+##### libamarok_ipod-mediadevice (module) #######
+
+tde_add_kpart( libamarok_ipod-mediadevice AUTOMOC
+  SOURCES ipodmediadevice.cpp
+  LINK amarok-shared
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)

amarok/src/metadata/CMakeLists.txt

@@ -0,0 +1,40 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( asf )
+add_subdirectory( audible )
+add_subdirectory( rmff )
+add_subdirectory( aac )
+add_subdirectory( wav )
+
+if( WITH_MP4V2 )
+  add_subdirectory( mp4 )
+else( )
+  add_subdirectory( m4a )
+endif( )
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TAGLIB_INCLUDE_DIRS}
+)
+
+
+##### metadata (static) #########################
+
+tde_add_library( metadata STATIC_PIC
+  SOURCES tplugins.cpp
+  LINK
+    tagasf-static tagaudible-static tagrealmedia-static
+    tagaac-static tagwav-static tagmp4-static
+)

amarok/src/metadata/aac/CMakeLists.txt

@@ -0,0 +1,23 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### tagaac (static) ###########################
+
+tde_add_library( tagaac STATIC_PIC
+  SOURCES
+    aacfiletyperesolver.cpp
+)

amarok/src/metadata/asf/CMakeLists.txt

@@ -0,0 +1,25 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TAGLIB_INCLUDE_DIRS}
+)
+
+
+##### tagasf (static) ###########################
+
+tde_add_library( tagasf STATIC_PIC
+  SOURCES
+    asfattribute.cpp asfproperties.cpp asftag.cpp
+    asffile.cpp taglib_asffiletyperesolver.cpp
+)

amarok/src/metadata/audible/CMakeLists.txt

@@ -0,0 +1,25 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### tagaudible (static) #######################
+
+tde_add_library( tagaudible STATIC_PIC
+  SOURCES
+    audibleproperties.cpp audibletag.cpp taglib_audiblefile.cpp
+    taglib_audiblefiletyperesolver.cpp
+)

amarok/src/metadata/m4a/CMakeLists.txt

@@ -0,0 +1,32 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TAGLIB_INCLUDE_DIRS}
+)
+
+
+##### tagmp4 (static) ###########################
+
+tde_add_library( tagmp4 STATIC_PIC
+  SOURCES
+    taglib_mp4filetyperesolver.cpp mp4file.cpp mp4itunestag.cpp mp4isobox.cpp
+    mp4isofullbox.cpp mp4skipbox.cpp mp4moovbox.cpp mp4mvhdbox.cpp
+    mp4ilstbox.cpp boxfactory.cpp mp4fourcc.cpp mp4udtabox.cpp mp4metabox.cpp
+    mp4tagsproxy.cpp mp4mdiabox.cpp mp4minfbox.cpp mp4audioproperties.cpp
+    mp4hdlrbox.cpp mp4stblbox.cpp mp4audiosampleentry.cpp mp4stsdbox.cpp
+    mp4sampleentry.cpp mp4trakbox.cpp mp4propsproxy.cpp itunesnambox.cpp
+    itunesartbox.cpp itunesalbbox.cpp itunescvrbox.cpp itunesgenbox.cpp
+    itunestrknbox.cpp itunesdaybox.cpp itunescmtbox.cpp itunesgrpbox.cpp
+    ituneswrtbox.cpp itunesdiskbox.cpp itunestmpobox.cpp itunesdatabox.cpp
+)

amarok/src/metadata/rmff/CMakeLists.txt

@@ -0,0 +1,26 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TAGLIB_INCLUDE_DIRS}
+)
+
+
+##### tagrealmedia (static) #####################
+
+tde_add_library( tagrealmedia STATIC_PIC
+  SOURCES
+    rmff.cpp taglib_realmediafile.cpp
+    taglib_realmediafiletyperesolver.cpp
+)

amarok/src/metadata/wav/CMakeLists.txt

@@ -0,0 +1,24 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### tagwav (static) ###########################
+
+tde_add_library( tagwav STATIC_PIC
+  SOURCES
+    wavproperties.cpp wavfile.cpp wavfiletyperesolver.cpp
+)

amarok/src/plugin/CMakeLists.txt

@@ -0,0 +1,30 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### plugin (static) ###########################
+
+add_custom_command( OUTPUT pluginconfig.moc.cpp
+  COMMAND
+    ${TQT_TMOC_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/pluginconfig.h -o pluginconfig.moc.cpp
+  DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/pluginconfig.h )
+
+tde_add_library( plugin STATIC_PIC
+  SOURCES plugin.cpp pluginconfig.moc.cpp
+)

amarok/src/scripts/CMakeLists.txt

@@ -0,0 +1,20 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( common )
+add_subdirectory( lyrics_astraweb )
+add_subdirectory( lyrics_lyrc )
+add_subdirectory( playlist2html )
+add_subdirectory( ruby_debug )
+add_subdirectory( score_default )
+add_subdirectory( score_impulsive )
+add_subdirectory( templates )
+add_subdirectory( webcontrol )

amarok/src/scripts/common/CMakeLists.txt

@@ -0,0 +1,12 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES Zeroconf.py Publisher.py DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/common )

amarok/src/scripts/lyrics_astraweb/CMakeLists.txt

@@ -0,0 +1,14 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES
+    COPYING README lyrics_astraweb.rb lyrics_astraweb.spec
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/lyrics_astraweb )

amarok/src/scripts/lyrics_lyrc/CMakeLists.txt

@@ -0,0 +1,13 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( PROGRAMS lyrics_lyrc.rb DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/lyrics_lyrc )
+install( FILES COPYING README lyrics_lyrc.spec DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/lyrics_lyrc )

amarok/src/scripts/playlist2html/CMakeLists.txt

@@ -0,0 +1,18 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( PROGRAMS
+    playlist2html.py PlaylistServer.py
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/playlist2html )
+
+install( FILES
+    Playlist.py README playlist2html.spec PlaylistServer.spec
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/playlist2html )

amarok/src/scripts/ruby_debug/CMakeLists.txt

@@ -0,0 +1,12 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES debug.rb DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/ruby_debug )

amarok/src/scripts/score_default/CMakeLists.txt

@@ -0,0 +1,18 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( PROGRAMS
+    score_default.rb
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/score_default )
+
+install( FILES
+    COPYING README score_default.spec
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/score_default )

amarok/src/scripts/score_impulsive/CMakeLists.txt

@@ -0,0 +1,18 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( PROGRAMS
+    score_impulsive.rb
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/score_impulsive )
+
+install( FILES
+    COPYING README score_impulsive.spec
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/score_impulsive )

amarok/src/scripts/templates/CMakeLists.txt

@@ -0,0 +1,14 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES
+    python_qt_template.py ruby_qt_template.rb amarok.rb
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/templates )

amarok/src/scripts/webcontrol/CMakeLists.txt

@@ -0,0 +1,22 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( PROGRAMS
+    WebControl.py
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/webcontrol )
+
+install( FILES
+    Globals.py Playlist.py README RequestHandler.py WebControl.spec
+    WebPublisher.py amarok_cut.png controlbackground.png main.css
+    main.js player_end.png player_pause.png player_play.png
+    player_start.png player_stop.png template.thtml vol_speaker.png
+    star.png smallstar.png
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/scripts/webcontrol )

amarok/src/statusbar/CMakeLists.txt

@@ -0,0 +1,32 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+include_directories(
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_BINARY_DIR}/amarok/src
+  ${CMAKE_BINARY_DIR}/amarok/src/amarokcore
+  ${CMAKE_SOURCE_DIR}/amarok/src
+  ${CMAKE_SOURCE_DIR}/amarok/src/amarokcore
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+
+##### statusbar (static) ########################
+
+tde_add_library( statusbar STATIC_PIC AUTOMOC
+  SOURCES
+    statusBarBase.cpp statusbar.cpp overlayWidget.cpp
+    popupMessage.cpp progressBar.cpp squeezedtextlabel.cpp
+    queueLabel.cpp
+  DEPENDENCIES amarokcore-static
+)

amarok/src/themes/CMakeLists.txt

@@ -0,0 +1,13 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( example )
+add_subdirectory( reinhardt )

amarok/src/themes/example/CMakeLists.txt

@@ -0,0 +1,12 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES stylesheet.css DESTINATION ${DATA_INSTALL_DIR}/amarok/themes/example )

amarok/src/themes/reinhardt/CMakeLists.txt

@@ -0,0 +1,14 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_subdirectory( images )
+
+install( FILES stylesheet.css DESTINATION ${DATA_INSTALL_DIR}/amarok/themes/reinhardt )

amarok/src/themes/reinhardt/images/CMakeLists.txt

@@ -0,0 +1,14 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+install( FILES
+    background.png transparency.png
+  DESTINATION ${DATA_INSTALL_DIR}/amarok/themes/reinhardt/images )

amarok/src/vis/CMakeLists.txt

@@ -0,0 +1,12 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+tde_conditional_add_subdirectory( WITH_LIBVISUAL libvisual )

amarok/src/vis/libvisual/CMakeLists.txt

@@ -0,0 +1,34 @@
+#################################################
+#
+#  (C) 2010-2011 Serghei Amelian
+#  serghei (DOT) amelian (AT) gmail.com
+#
+#  Improvements and feedback are welcome
+#
+#  This file is released under GPL >= 2
+#
+#################################################
+
+add_definitions(
+  ${SDL_CFLAGS_OTHER}
+)
+
+include_directories(
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${SDL_INCLUDE_DIRS}
+  ${LIBVISUAL_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+
+##### amarok_libvisual (executable) #############
+
+tde_add_executable( amarok_libvisual
+  SOURCES libvisual.cpp
+  LINK ${SDL_LIBRARIES} ${LIBVISUAL_LIBRARIES}
+  DESTINATION ${BIN_INSTALL_DIR}
+)

config.h.cmake

@@ -0,0 +1,16 @@
+#cmakedefine SIZEOF_INT @SIZEOF_INT@
+#cmakedefine SIZEOF_LONG @SIZEOF_LONG@
+#cmakedefine HAVE_STDINT_H 1
+#cmakedefine HAVE_SYSTEMS_H 1
+#cmakedefine HAVE_FABSF 1
+#cmakedefine HAVE_LIBVISUAL 1
+#cmakedefine HAVE_INOTIFY 1
+#cmakedefine HAVE_STATVFS 1
+
+#cmakedefine HAVE_ITDB_MEDIATYPE 1
+#cmakedefine HAVE_LIBGPOD_060 1
+#cmakedefine HAVE_MP4V2 1
+#cmakedefine HAVE_TUNEPIMP 1
+
+#cmakedefine TAGLIB_15 1
+#cmakedefine HAVE_QGLWIDGET 1