################################################################################
# XDG Desktop Portal implementation for TDE                                    #
# Copyright (C) 2024 Mavridis Philippe <mavridisf@gmail.com>                   #
#                                                                              #
# Improvements and feedback are welcome!                                       #
# This software is licensed under the terms of the GNU GPL v3 license.         #
################################################################################

include_directories(
    ${CMAKE_CURRENT_BINARY_DIR}
    ${DBUS_TQT_INCLUDE_DIRS}
)

link_directories(
    ${DBUS_TQT_LIBRARY_DIRS}
)

set(interfaces account email filechooser)
set(interface_HDRS introspectableInterface.h desktopNode.h dbusbaseNode.h)
set(interface_SRCS introspectableInterface.cpp desktopNode.cpp dbusbaseNode.cpp)

foreach(interface IN LISTS interfaces)
    list(APPEND interface_HDRS ${interface}Interface.h ${interface}Proxy.h)
    list(APPEND interface_SRCS ${interface}Interface.cpp ${interface}Proxy.cpp)
endforeach()

add_custom_command(
    OUTPUT ${interface_HDRS} ${interface_SRCS}
    COMMAND ${DBUSXML2QT3_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/interfaces.xml
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/interfaces.xml
    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
)

tde_add_library(portalinterfaces STATIC_PIC AUTOMOC
    SOURCES ${interface_SRCS}
    LINK ${DBUS_TQT_LIBRARIES}
)

configure_file(org.freedesktop.impl.portal.desktop.tde.service.cmake
               org.freedesktop.impl.portal.desktop.tde.service @ONLY)

configure_file(xdg-desktop-portal-tde.desktop.cmake
               xdg-desktop-portal-tde.desktop @ONLY)

install(FILES tde.portal DESTINATION ${XDG_PREFIX}/share/xdg-desktop-portal/portals)

install(FILES tde-portals.conf DESTINATION ${XDG_PREFIX}/share/xdg-desktop-portal)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.freedesktop.impl.portal.desktop.tde.service
        DESTINATION ${DBUS_SESSION_DIRECTORY})

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/xdg-desktop-portal-tde.desktop
        DESTINATION ${SHARE_INSTALL_PREFIX}/applications)