tqt3/src/kernel/CMakeLists.txt

include_directories(
  ${CMAKE_BINARY_DIR}
  ${CMAKE_CURRENT_BINARY_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}
  ${CMAKE_BINARY_DIR}/include
  ${CMAKE_SOURCE_DIR}/mkspecs/linux-g++-64
  ${FREETYPE_INCLUDE_DIRS}
  ${CMAKE_SOURCE_DIR}/src/3rdparty/opentype
  ${NAS_INCLUDE_DIRS}
  ${GLIB2_INCLUDE_DIRS}
  ${X11_X11_INCLUDE_PATH}
  ${X11_Xutil_INCLUDE_PATH}
  ${X11_Xft_INCLUDE_PATH}
  ${X11_Xshape_INCLUDE_PATH}
  ${X11_Xinput_INCLUDE_PATH}
  ${X11_Xinerama_INCLUDE_PATH}
  ${X11_Xrandr_INCLUDE_PATH}
  ${X11_Xrender_INCLUDE_PATH}
  ${X11_XSync_INCLUDE_PATH}
  ${X11_Xkblib_INCLUDE_PATH}
  ${X11_SM_INCLUDE_PATH}
  ${X11_Xcursor_INCLUDE_PATH}
  ${LIB_MNG_INCLUDE_DIRS}
  ${JPEG_INCLUDE_DIR}
  ${PNG_INCLUDE_DIRS}
  ${ZLIB_INCLUDE_DIRS}
)

link_directories()


##### kernel (static)

set( target kernel )
set( _SRC_ qtaddons_x11.cpp
           tqttdeintegration_x11.cpp
           qapplication_x11.cpp
           qclipboard_x11.cpp
           qcolor_x11.cpp
           qcursor_x11.cpp
           qdnd_x11.cpp
           qdesktopwidget_x11.cpp
           qfont_x11.cpp
           qmotifdnd_x11.cpp
           qpixmap_x11.cpp
           qpaintdevice_x11.cpp
           qpainter_x11.cpp
           qregion_x11.cpp
           qwidget_x11.cpp
           qwidgetcreate_x11.cpp
           qfontengine_x11.cpp
           qprinter_unix.cpp
           qpsprinter.cpp
           qprocess_unix.cpp
           qthread_unix.cpp
           qabstractlayout.cpp
           qucomextra.cpp
           qaccel.cpp
           qapplication.cpp
           qasyncimageio.cpp
           qasyncio.cpp
           qbitmap.cpp
           qclipboard.cpp
           qcolor.cpp
           qcolor_p.cpp
           qconnection.cpp
           qcursor.cpp
           qdragobject.cpp
           qdrawutil.cpp
           qdropsite.cpp
           qevent.cpp
           qeventloop.cpp
           qfocusdata.cpp
           qfont.cpp
           qfontdatabase.cpp
           qguardedptr.cpp
           qiconset.cpp
           qimage.cpp
           qimageformatplugin.cpp
           qkeysequence.cpp
           qlayout.cpp
           qlayoutengine.cpp
           qtranslator.cpp
           qmetaobject.cpp
           qmime.cpp
           qmovie.cpp
           qnetworkprotocol.cpp
           qobject.cpp
           qobjectcleanuphandler.cpp
           qpainter.cpp
           qpalette.cpp
           qpaintdevicemetrics.cpp
           qpicture.cpp
           qpixmap.cpp
           qpixmapcache.cpp
           qpointarray.cpp
           qpoint.cpp
           qpolygonscanner.cpp
           qprinter.cpp
           qprocess.cpp
           qrect.cpp
           qregion.cpp
           qsignal.cpp
           qsignalmapper.cpp
           qsize.cpp
           qsizegrip.cpp
           qstyle.cpp
           qsocketnotifier.cpp
           qstylesheet.cpp
           qthread.cpp
           qtimer.cpp
           qurl.cpp
           qlocalfs.cpp
           qurloperator.cpp
           qurlinfo.cpp
           qwidget.cpp
           qwmatrix.cpp
           qvariant.cpp
           qrichtext.cpp
           qinternal.cpp
           qrichtext_p.cpp
           qgplugin.cpp
           qsimplerichtext.cpp
           qscriptengine.cpp
           qtextlayout.cpp
           qtextengine.cpp
           qaccessible.cpp
)

if( WITH_MODULE_INPUTMETHOD )
    list( APPEND _SRC_
        qinputcontext.cpp
        qinputcontext_x11.cpp
    )
endif()

if( WITH_SOUND )
    list( APPEND _SRC_ qsound.cpp qsound_x11.cpp )
endif()

if( WITH_GLIBMAINLOOP )
    list( APPEND _SRC_ qeventloop_x11_glib.cpp qeventloop_unix_glib.cpp )
 else()
    list( APPEND _SRC_ qeventloop_x11.cpp qeventloop_unix.cpp )
endif()

if( WITH_XFT )
    list( APPEND _SRC_ ../3rdparty/opentype/ftxopentype.c )
endif()

set( _EXTRA_HEADERS_
    ntqdesktopwidget.h
    ntqsessionmanager.h
)

# Setup optional image formats support
set( _PNG_libraries ${PNG_LIBRARIES} )
set( _JPEG_libraries ${JPEG_LIBRARIES} )
set( _MNG_libraries ${MNG_LIBRARIES} ${JPEG_LIBRARIES} )

unset( _img_flags )
unset( _img_libraries )

foreach( _imgfmt PNG JPEG MNG )
    if( BUILD_IMGFMT_PLUGIN_${_imgfmt} )
        string( TOLOWER "plugins/src/imageformats/${_imgfmt}/main.cpp" _plugin_main_src )
        set( _plugin_main_src ${CMAKE_SOURCE_DIR}/${_plugin_main_src} )
        string( TOLOWER "q${_imgfmt}" _plugin_lib )
        tde_add_library( ${_plugin_lib} SHARED
          SOURCES ${_plugin_main_src}
          LINK tqt-mt-shared ${_${_imgfmt}_libraries}
          DESTINATION "${QT_INSTALL_PLUGINS}/imageformats"
        )
        tqt_automoc( ${_plugin_lib}-shared )
     elseif( WITH_IMGFMT_${_imgfmt} )
        string( TOLOWER "q${_imgfmt}io.cpp" _imgfmt_io_src )
        list( APPEND _SRC_ ${_imgfmt_io_src} )
        list( APPEND _img_libraries ${_${_imgfmt}_libraries} )
    endif()
    if( NOT WITH_IMGFMT_${_imgfmt} OR BUILD_IMGFMT_PLUGIN_${_imgfmt} )
        list( APPEND _img_flags TQT_NO_IMAGEIO_${_imgfmt} )
    endif()
endforeach()

if( WITH_IMGFMT_GIF )
    list( APPEND _img_flags QT_BUILTIN_GIF_READER=1 )
endif()

tde_add_library( ${target} STATIC_PIC

  SOURCES
        ${_SRC_}
  LINK
     ${LIBICE_LIBRARIES}
     ${NAS_LIBRARIES}
     ${X11_X11_LIB}
     ${X11_Xft_LIB}
     ${X11_Xext_LIB}
     ${X11_Xinput_LIB}
     ${X11_Xinerama_LIB}
     ${X11_Xrandr_LIB}
     ${X11_Xrender_LIB}
     ${X11_SM_LIB}
     ${X11_Xcursor_LIB}
     ${ZLIB_LIBRARIES}
     ${LIBFONTCONFIG_LIBRARIES}
     ${GLIB2_LIBRARIES}
     ${_img_libraries}

  DEPENDENCIES
    tqt-includes
)

tqt_automoc( ${target}-static
    INCLUDES ${_EXTRA_HEADERS_} AUTO )

list( APPEND tqtlib_embed ${target}-static )
set( tqtlib_embed ${tqtlib_embed} PARENT_SCOPE )

set_property( TARGET ${target}-static
              APPEND PROPERTY COMPILE_DEFINITIONS
              ${NO_SOUND} ${NAS_SUPPORT} ${USE_GLIBMAINLOOP}
              ${NO_XFTFREETYPE} ${USE_XFT2_HEADER} ${NO_SHAPE} ${TABLET_SUPPORT}
              ${NO_XINERAMA} ${NO_XRANDR} ${NO_XRENDER} ${NO_XSYNC}
              ${NO_XKB} ${NO_SM} ${NO_XCURSOR} ${BUILTIN_GIF_READER}
              ${QT_ACCESSIBILITY_SUPPORT} ${_img_flags}
)