include_directories(
  ${CMAKE_BINARY_DIR}
  ${CMAKE_CURRENT_BINARY_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}/../shared
  ${CMAKE_SOURCE_DIR}/mkspecs/linux-g++-64
  ${CMAKE_BINARY_DIR}/include
  ${ZLIB_INCLUDE_DIRS}
)

link_directories()


##### tqtdesignercore (shared)

set( target tqtdesignercore )

set( ${target}_SOURCES
    command.cpp
    formwindow.cpp
    defs.cpp
    layout.cpp
    mainwindow.cpp
    mainwindowactions.cpp
    metadatabase.cpp
    pixmapchooser.cpp
    propertyeditor.cpp
    resource.cpp
    sizehandle.cpp
    orderindicator.cpp
    widgetfactory.cpp
    hierarchyview.cpp
    listboxeditorimpl.cpp
    newformimpl.cpp
    workspace.cpp
    listvieweditorimpl.cpp
    customwidgeteditorimpl.cpp
    paletteeditorimpl.cpp
    styledbutton.cpp
    iconvieweditorimpl.cpp
    multilineeditorimpl.cpp
    formsettingsimpl.cpp
    asciivalidator.cpp
    designerapp.cpp
    designerappiface.cpp
    actioneditorimpl.cpp
    actionlistview.cpp
    actiondnd.cpp
    project.cpp
    projectsettingsimpl.cpp
    sourceeditor.cpp
    outputwindow.cpp
    ../shared/widgetdatabase.cpp
    ../shared/parser.cpp
    pixmapcollection.cpp
    previewframe.cpp
    previewwidgetimpl.cpp
    paletteeditoradvancedimpl.cpp
    sourcefile.cpp
    wizardeditorimpl.cpp
    qcompletionedit.cpp
    timestamp.cpp
    formfile.cpp
    widgetaction.cpp
    propertyobject.cpp
    startdialogimpl.cpp
    syntaxhighlighter_html.cpp
    connectionitems.cpp
    editfunctionsimpl.cpp
    variabledialogimpl.cpp
    listviewdnd.cpp
    listboxdnd.cpp
    listdnd.cpp
    listboxrename.cpp
    connectiontable.cpp
    popupmenueditor.cpp
    menubareditor.cpp

    listboxeditor.ui
    editfunctions.ui
    newform.ui
    listvieweditor.ui
    customwidgeteditor.ui
    paletteeditor.ui
    iconvieweditor.ui
    preferences.ui
    multilineeditor.ui
    formsettings.ui
    about.ui
    pixmapfunction.ui
    createtemplate.ui
    actioneditor.ui
    projectsettings.ui
    finddialog.ui
    replacedialog.ui
    gotolinedialog.ui
    pixmapcollectioneditor.ui
    previewwidget.ui
    paletteeditoradvanced.ui
    wizardeditor.ui
    listeditor.ui
    startdialog.ui
    richtextfontdialog.ui
    connectiondialog.ui
    variabledialog.ui
    configtoolboxdialog.ui

    embed_image_collection.cpp
)

set( ${target}_INCLUDES
    command.h
    defs.h
    formwindow.h
    layout.h
    mainwindow.h
    metadatabase.h
    pixmapchooser.h
    propertyeditor.h
    resource.h
    sizehandle.h
    orderindicator.h
    widgetfactory.h
    hierarchyview.h
    listboxeditorimpl.h
    newformimpl.h
    workspace.h
    listvieweditorimpl.h
    customwidgeteditorimpl.h
    paletteeditorimpl.h
    styledbutton.h
    iconvieweditorimpl.h
    multilineeditorimpl.h
    formsettingsimpl.h
    asciivalidator.h
    ../interfaces/widgetinterface.h
    ../interfaces/actioninterface.h
    ../interfaces/filterinterface.h
    ../interfaces/designerinterface.h
    designerapp.h
    designerappiface.h
    actioneditorimpl.h
    actionlistview.h
    actiondnd.h
    project.h
    projectsettingsimpl.h
    sourceeditor.h
    outputwindow.h
    ../shared/widgetdatabase.h
    ../shared/parser.h
    previewframe.h
    previewwidgetimpl.h
    paletteeditoradvancedimpl.h
    pixmapcollection.h
    sourcefile.h
    wizardeditorimpl.h
    qcompletionedit.h
    timestamp.h
    formfile.h
    widgetaction.h
    propertyobject.h
    startdialogimpl.h
    syntaxhighlighter_html.h
    connectionitems.h
    editfunctionsimpl.h
    variabledialogimpl.h
    listviewdnd.h
    listboxdnd.h
    listdnd.h
    listboxrename.h
    connectiontable.h
    popupmenueditor.h
    menubareditor.h
)

if( WITH_MODULE_SQL )
  list( APPEND ${target}_SOURCES
    database.cpp dbconnectionimpl.cpp dbconnectionsimpl.cpp
    dbconnections.ui dbconnection.ui dbconnectioneditor.ui
  )
  list( APPEND ${target}_INCLUDES
    database.h dbconnectionimpl.h dbconnectionsimpl.h
)
endif()

if( WITH_MODULE_TABLE )
  list( APPEND ${target}_SOURCES
    tableeditorimpl.cpp
    tableeditor.ui
  )
  list( APPEND ${target}_INCLUDES tableeditorimpl.h )
endif()

tde_add_library( ${target} SHARED
  SOURCES ${${target}_SOURCES}
  LINK tqt-mt-shared tqassistantclient-shared tqui-shared
  VERSION 1.0.0
  DESTINATION ${LIB_INSTALL_DIR}
  DEPENDENCIES tquic
)

set_property(
  TARGET ${target}-shared
  APPEND PROPERTY COMPILE_DEFINITIONS
    DESIGNER
    QT_INTERNAL_XML
    QT_INTERNAL_WORKSPACE
    QT_INTERNAL_TABLE
)

tqt_automoc( ${target}-shared INCLUDES ${${target}_INCLUDES} )


##### embed images

file(
  GLOB ${target}_IMAGES
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}/images/*.png
)
list( SORT ${target}_IMAGES )
add_custom_command( OUTPUT embed_image_collection.cpp
  COMMAND ${UIC_EXECUTABLE}
    -embed ${target} ${${target}_IMAGES}
    -o ${CMAKE_CURRENT_BINARY_DIR}/embed_image_collection.cpp
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  DEPENDS tquic
  COMMENT "Embed images for ${target}"
)
add_custom_target( ${target}-embed-images
  COMMENT "Generate embed images for ${target}"
  DEPENDS ${CURRENT_CMAKE_BINARY_DIR}/embed_image_collection.cpp
)


##### other data

tde_create_translated_desktop(
  SOURCE tqdesigner.desktop
  DESTINATION ${QT_INSTALL_SHARE}/applications
)

install(
  FILES images/appicon.png
  DESTINATION ${QT_INSTALL_SHARE}/pixmaps
  RENAME tqdesigner.png
)

if( BUILD_TRANSLATIONS )
  tqt_create_translation()
endif()

file(
  GLOB templates
  RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}/../templates/*
)
list( SORT templates )
install(
  FILES ${templates}
  DESTINATION ${QT_INSTALL_DATA}/templates
)