include_directories(
  ${CMAKE_BINARY_DIR}
  ${CMAKE_CURRENT_BINARY_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}
  ${CMAKE_SOURCE_DIR}/mkspecs/linux-g++-64
  ${CMAKE_BINARY_DIR}/include
  ${ZLIB_INCLUDE_DIRS}
)

link_directories()


##### subdirectories

tde_auto_add_subdirectories()


##### tqassistant (executable)

set( target tqassistant )

tde_add_executable( ${target}
  SOURCES
    main.cpp
    helpwindow.cpp
    topicchooserimpl.cpp
    docuparser.cpp
    helpdialogimpl.cpp
    settingsdialogimpl.cpp
    index.cpp
    profile.cpp
    config.cpp

    mainwindow.ui
    topicchooser.ui
    finddialog.ui
    helpdialog.ui
    settingsdialog.ui
    tabbedbrowser.ui

    embed_image_collection.cpp

  LINK
    tqt-mt-shared
    tqassistantclient-shared

  DESTINATION
    ${BIN_INSTALL_DIR}

  DEPENDENCIES
    tquic
)

set_property(
  TARGET ${target}
  APPEND PROPERTY COMPILE_DEFINITIONS
    QT_INTERNAL_NETWORK
    QT_INTERNAL_XML
)

tqt_automoc( ${target} )


##### embed images

file(
    GLOB ${target}_IMAGES
    RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
    ${CMAKE_CURRENT_SOURCE_DIR}/images/*.png
)
list( SORT ${target}_IMAGES )
add_custom_command( OUTPUT embed_image_collection.cpp
    COMMAND ${UIC_EXECUTABLE} -embed ${target} ${${target}_IMAGES}
      -o ${CMAKE_CURRENT_BINARY_DIR}/embed_image_collection.cpp
    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
    DEPENDS tquic
    COMMENT "Embed images for ${target}"
)
add_custom_target( ${target}-embed-images
    COMMENT "Generate embed images for ${target}"
    DEPENDS ${CURRENT_CMAKE_BINARY_DIR}/embed_image_collection.cpp
)


##### other data

tde_create_translated_desktop(
  SOURCE ${target}.desktop
  DESTINATION ${QT_INSTALL_SHARE}/applications
)

if( BUILD_TRANSLATIONS )
  tqt_create_translation()
endif()

install(
  FILES images/appicon.png
  DESTINATION ${QT_INSTALL_SHARE}/pixmaps
  RENAME ${target}.png
)