include_directories(
  ${CMAKE_BINARY_DIR}
  ${CMAKE_CURRENT_BINARY_DIR}
  ${CMAKE_CURRENT_SOURCE_DIR}
  ${CMAKE_BINARY_DIR}/include
  ${CMAKE_SOURCE_DIR}/mkspecs/linux-g++-64
  ${CMAKE_SOURCE_DIR}/src/kernel
)

link_directories()


##### styles (static)

set( target styles )
set( _SRC_ qcommonstyle.cpp
           qstyleplugin.cpp
           qstylefactory.cpp
)

set( _STYLE_MOTIF_SRC_     qmotifstyle.cpp     )
set( _STYLE_WINDOWS_SRC_   qwindowsstyle.cpp   )
set( _STYLE_CDE_SRC_       qcdestyle.cpp       )
set( _STYLE_MOTIFPLUS_SRC_ qmotifplusstyle.cpp )
set( _STYLE_SGI_SRC_       qsgistyle.cpp       )
set( _STYLE_COMPACT_SRC_   qcompactstyle.cpp   )
set( _STYLE_INTERLACE_SRC_ qinterlacestyle.cpp )
set( _STYLE_PLATINUM_SRC_  qplatinumstyle.cpp  )

# check style dependencies
tqt_requires( WITH_STYLE_CDE       WITH_STYLE_MOTIF   )
tqt_requires( WITH_STYLE_MOTIFPLUS WITH_STYLE_MOTIF   )
tqt_requires( WITH_STYLE_SGI       WITH_STYLE_MOTIF   )
tqt_requires( WITH_STYLE_INTERLACE WITH_STYLE_WINDOWS )
tqt_requires( WITH_STYLE_PLATINUM  WITH_STYLE_WINDOWS )
tqt_requires( WITH_STYLE_COMPACT   WITH_STYLE_WINDOWS )

# styles unsupported on X11
set ( _disabled_styles
    TQT_NO_STYLE_WINDOWSXP
    TQT_NO_STYLE_AQUA
    TQT_NO_STYLE_POCKETPC
    TQT_NO_STYLE_MAC
)

foreach( _style MOTIF WINDOWS CDE MOTIFPLUS SGI COMPACT INTERLACE PLATINUM )
    if( WITH_STYLE_${_style} )
        list( APPEND _SRC_ "${_STYLE_${_style}_SRC_}" )
     else( )
        list( APPEND _disabled_styles "TQT_NO_STYLE_${_style}" )
    endif( )
endforeach( )

tde_add_library( ${target} STATIC_PIC

  SOURCES
        ${_SRC_}

  DEPENDENCIES
    tqt-includes
)

tqt_automoc( ${target}-static )

list( APPEND tqtlib_embed ${target}-static )
set( tqtlib_embed ${tqtlib_embed} PARENT_SCOPE )

set_property(
    TARGET ${target}-static
    APPEND PROPERTY COMPILE_DEFINITIONS ${_disabled_styles}
)