INCLUDE_DIRECTORIES(${CMAKE_BINARY_DIR}/src/svnqt)
FILE(GLOB hdr RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "*.h")
SET(kded_tdesvnd_src
    tdesvnd_dcop.cpp
    ${hdr}
   )

KDE3_ADD_MOC_FILES(kded_tdesvnd_src tdesvnd_dcop.h)

KDE3_ADD_DCOP_SKELS(kded_tdesvnd_src
    tdesvnd_dcop.h)

KDE3_ADD_KPART(kded_tdesvnd ${kded_tdesvnd_src})

TARGET_LINK_LIBRARIES(kded_tdesvnd
    svnqt
    ksvnwidgets
    tdesvnhelpers
    tdesvncfgreader
    ${QT_AND_TDECORE_LIBS} ${KDE3_KIO_LIBRARY} ${KDE3_DCOP_LIBRARY}
    ${KDE3_UI_LIBRARY} ${KDE3_WALLET_LIBRARY} 
    ${KDE3_KINIT_KDED_LIBRARY})

SET_TARGET_PROPERTIES(kded_tdesvnd
    PROPERTIES
    LINK_FLAGS "${LINK_NO_UNDEFINED} ${_BASE_LDADD} ${APR_EXTRA_LIBFLAGS} ${APU_EXTRA_LIBFLAGS} -module")

INSTALL(TARGETS kded_tdesvnd
    RUNTIME DESTINATION ${BIN_INSTALL_DIR}
    LIBRARY DESTINATION ${PLUGIN_INSTALL_DIR})

KDESVN_GENERATE_LIBTOOL_FILE(kded_tdesvnd)

IF(KDE3_KDECONFIG_EXECUTABLE)
    EXECUTE_PROCESS(COMMAND ${KDE3_KDECONFIG_EXECUTABLE} "--version" OUTPUT_VARIABLE output)
    STRING(REGEX MATCH "KDE: [0-9]+\\.[0-9]+\\.[0-9]+" KDEVERSION "${output}")
    STRING(REGEX REPLACE "^KDE: " "" KDEVERSION "${KDEVERSION}")
ENDIF(KDE3_KDECONFIG_EXECUTABLE)
SET(KDE_MIN_VERSION "3.5.0")
MACRO_ENSURE_VERSION(${KDE_MIN_VERSION} ${KDEVERSION} VERSION_OK)

IF(VERSION_OK)
    SET(ACTION_MENU "X-KDE-GetActionMenu=kded tdesvnd getActionMenu(KURL::List)")
ELSE(VERSION_OK)
    SET(ACTION_MENU "Actions=Update;Commit;Add;Delete;Blame;Log;Diff;Checkout;Export;Info;Addnew;Switch;Revert;Rename;Tree")
ENDIF(VERSION_OK)

CONFIGURE_FILE(tdesvn_subversion.desktop.in
    ${CMAKE_CURRENT_BINARY_DIR}/tdesvn_subversion.desktop @ONLY)

INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/tdesvn_subversion.desktop
    DESTINATION ${DATA_INSTALL_DIR}/konqueror/servicemenus)

INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tdesvnd.desktop
    DESTINATION ${SERVICES_INSTALL_DIR}/kded)