# Contributor: Slávek Banko <slavek.banko@axis.cz>

_mod=akode
_cat=dependencies/
_kdemod="${_mod/tde/kde}"

pkgname="tde-${_mod}"
pkgver=14.0.13
pkgrel=1
pkgdesc="akode plugin for aRts"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
groups=('tde-extra')
depends=('alsa-plugins'
	'alsa-tools'
	'alsa-utils'
	'audiofile'
	'libmad'
	'libogg'
	'libvorbis'
	'pulseaudio-alsa')
makedepends=('tde-cmake-trinity')
provides=("${_mod}")
conflicts=("kdemod3-${_mod}" "${_mod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!emptydirs')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz")
md5sums=('cb44fed3d78b5c542f688aad8dd7cc5e')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
      -DWITH_ALL_OPTIONS=ON \
      -DWITH_JACK_SINK=OFF

   msg "Building $pkgname..."
   ninja $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   DESTDIR="$pkgdir" ninja -j1 install
}