tde-packaging/arch/tde-base/tde-tdegraphics/PKGBUILD

# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: e1z0 <marcinkeviciusjustinas at gmail dot com>

pkgname=tde-tdegraphics
pkgver=14.0.10
pkgrel=1
pkgdesc="Trinity Desktop Graphics Components"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdegraphics'
license=('GPL')
groups=('tde-base')
depends=('tde-tdelibs' 'libgphoto2' 'fribidi' 'sane')
makedepends=('pkgconfig' 'cmake' 'imlib')
provides=('tdegraphics')
conflicts=('trinity-tdegraphics' 'trinity-kdegraphics')
replaces=('trinity-tdegraphics')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdegraphics-trinity-${pkgver}.tar.xz"
        'bp000-d19460fd6e.diff'
        'bp001-866f96c1f4.diff')
md5sums=('0b069eb140a9f8b8bbe4556f1bd313d9'
         'c5ccbf331b4b0b6a0af61687cc3308a5'
         'bd4a586fb17963697afceef79adc35a5')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd ${srcdir}/${pkgname#*-}-trinity-${pkgver}
   patch -p1 < ${srcdir}/bp000-d19460fd6e.diff
   patch -p1 < ${srcdir}/bp001-866f96c1f4.diff

   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
     -DCMAKE_VERBOSE_MAKEFILE=ON \
     -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
     -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build
  make -j1 DESTDIR="${pkgdir}" install
}