tde-packaging/arch/3.5.13/trinity-extras/trinity-kdepim/PKGBUILD

# Maintainer: Calvin Morrison <mutantturkey@gmail.com>

pkgname=trinity-kdepim
pkgver=3513
pkgrel=1.0
arch=('i686' 'x86_64')
url='http://www.trinitydesktop.com'
license=('GPL')
groups=('trinity-extras')
pkgdesc="Trinity Personal Information Management suite"
depends=('trinity-kdebase'
         'trinity-arts'
         'trinity-kdelibs'
         'gpgme'
         'boost'
         'gnokii'
         'trinity-libcaldav'
         'trinity-libcarddav')
makedepends=('pkgconfig' 'cmake' 'imake' 'fribidi')
# 'poppler-qt'
provides=('trinity-kdepim')
conflicts=('trinity-kdepim')
replaces=('trinity-kdepim')
options=('libtool' '!strip')
#source=('http://mirror.its.uidaho.edu/pub/trinity/releases/3.5.13/kdepim-3.5.13.tar.gz')
source=('http://anduin.linuxfromscratch.org/sources/trinity/kdepim-3.5.13.tar.gz')
md5sums=('4488062d5400bdd99642fe0b72ebcf9a')

_svnmod=kdepim
trinity_prefix="/opt/trinity"

build() {

  msg "Setting PATH, CMAKE and Trinity Environment variables"
  export CMAKE_PREFIX_PATH=/opt/qt:/opt/trinity
  if [[ -r /etc/profile.d/qt3.sh ]]; then
    . /etc/profile.d/qt3.sh
    [[ -n $QTDIR ]] && _qtdir=$QTDIR
  else
    [[ ${PATH%%:*} =~ ${_qtdir}/bin ]] || export PATH=${_qtdir}/bin:$PATH
  fi

   export CMAKE_INCLUDE_PATH=/opt/qt/include:/opt/qt/include/tqt:/usr/include/dbus-1.0:/opt/trinity/include:/opt/trinity/include/libkrandr:/usr/include
   export LD_LIBRARY_PATH=/opt/trinity/lib:/opt/trinity/lib/kde3:$LD_LIBRARY_PATH
   export PKG_CONFIG_PATH=:/opt/trinity/lib/pkgconfig:/opt/qt/lib/pkgconfig

  cd $srcdir
  msg "Creating out-of-source build directory: ${srcdir}/build"
  mkdir -p build
  cd build

  msg "Starting cmake..."
  cmake ${srcdir}/${_svnmod} \
    -DCMAKE_INSTALL_PREFIX=${trinity_prefix} \
    -DCMAKE_VERBOSE_MAKEFILE=ON \
    -DWITH_SASL=ON \
    -DWITH_NEWDISTRLISTS=ON \
    -DWITH_GNOKII=ON \
    -DWITH_EXCHANGE=ON \
    -DWITH_EGROUPWARE=ON \
    -DWITH_KOLAB=ON \
    -DWITH_SLOX=ON \
    -DWITH_GROUPWISE=ON \
    -DWITH_FEATUREPLAN=ON \
    -DWITH_GROUPDAV=ON \
    -DWITH_BIRTHDAYS=ON \
    -DWITH_NEWEXCHANGE=ON \
    -DWITH_SCALIX=ON \
    -DWITH_CALDAV=ON \
    -DWITH_CARDDAV=ON \
    -DWITH_INDEXLIB=ON \
    -DWITH_ARTS=ON \
    -DBUILD_ALL=ON
  make

#     -DWITH_PDF=ON \ (waiting on poppler-qt3)
#     -DWITH_QT3=ON \
#     -DQTDIR=/opt/qt \
#     -DQT_LIBRARY_DIRS=/opt/qt/lib \
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build

  make DESTDIR="$pkgdir/" install

  cd ${startdir}
}