tde-packaging/arch/tde-core/tde-tqca-tls/PKGBUILD

# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: Pawel 'l0ner' Soltys <pwslts@gmail.com>
# Contributor: Calvin Morrison <mutantturkey@gmail.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tqca-tls
pkgver=14.0.10
pkgrel=1
pkgdesc="Trinity SSL/TLS plugin for TQt Cryptographic Architecture (TQCA)"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tqca-tls'
license=('GPL')
groups=('tde-core')
depends=('tde-tqtinterface' 'openssl-1.0')
makedepends=('pkgconfig' 'cmake')
provides=('tqca-tls')
conflicts=('trinity-tqca-tls')
replaces=('trinity-tqca-tls')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/dependencies/tqca-tls-trinity-${pkgver}.tar.xz")
md5sums=('6347f50dd8b44cc1f7a35329bd578ba1')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity
[ -n "$QTDIR" ] || QTDIR=${TDEDIR}/tqt3

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${QTDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_GCC_VISIBILITY=ON

   msg "Building - $pkgname..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}