###########################################
#                                         #
#  Improvements and feedback are welcome  #
#                                         #
#  This file is released under GPL >= 3   #
#                                         #
###########################################

# required stuff
find_package( TQt )
find_package( TDE )

tde_setup_architecture_flags( )

include(TestBigEndian)
test_big_endian(WORDS_BIGENDIAN)

tde_setup_largefiles( )


##### check for gcc visibility support

if( WITH_GCC_VISIBILITY )
  tde_setup_gcc_visibility( )
endif( WITH_GCC_VISIBILITY )


##### check for tdehwlib

if( WITH_TDEHWLIB )
  tde_save_and_set( CMAKE_REQUIRED_INCLUDES "${TDE_INCLUDE_DIR}" )
  check_cxx_source_compiles( "
    #include <kdemacros.h>
      #ifndef __TDE_HAVE_TDEHWLIB
      #error tdecore is not build with tdehwlib
      #endif
      int main() { return 0; } "
    HAVE_TDEHWLIB
  )
  tde_restore( CMAKE_REQUIRED_INCLUDES )
  if( NOT HAVE_TDEHWLIB )
    tde_message_fatal( "tdehwlib is required, but not built in tdecore" )
  endif( NOT HAVE_TDEHWLIB )
  set( TDEHW_LIBRARIES "tdehw-shared" )
endif( )


##### check for NVidia support

if( WITH_NVCONTROL )
  set( NVCONTROL_FOUND false)

  find_path( NVCONTROL_INCLUDE_DIR NAMES "NVCtrlLib.h" PATH_SUFFIXES "NVCtrl" )
  find_library( NVCONTROL_LIBRARIES NAMES XNVCtrl )
  pkg_search_module( XEXT xext )

  if( NVCONTROL_LIBRARIES AND NVCONTROL_INCLUDE_DIR )
    set( NVCONTROL_FOUND true)
  endif( NVCONTROL_LIBRARIES AND NVCONTROL_INCLUDE_DIR )

  if( NVCONTROL_FOUND )
    set( HAVE_NVCONTROL 1 )
   else()
    tde_message_fatal( "NVidia support has been requested but <NVCtrlLib.h> or libXNVCtrl were not found on your system" )
  endif( NVCONTROL_FOUND )

endif( WITH_NVCONTROL )