conversion to the cmake building system

Signed-off-by: gregory guy <g-gregory@gmx.fr>

CMakeLists.txt

@@ -0,0 +1,75 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( kerberostray )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckSymbolExists      )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### user requested modules
+
+option( BUILD_ALL "Build all" ON                             )
+option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H )
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po ) 
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,62 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+tde_setup_largefiles( )
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  tde_setup_gcc_visibility( )
+endif( WITH_GCC_VISIBILITY )
+
+
+##### check for tdeldap
+
+find_library( HAVE_LIBTDELDAP tdeldap )
+if( HAVE_LIBTDELDAP )
+   set( LIBTDELDAP_LIBRARIES "tdeldap" )
+  else()
+   tde_message_fatal( "libtdeldap is required but was not found on your system" )
+endif( )
+
+
+##### check for krb5
+
+pkg_search_module( KRB5 krb5 )
+if( NOT KRB5_FOUND)
+  if( NOT DEFINED KRB5_CONFIG_EXECUTABLE )
+    find_program( KRB5_CONFIG_EXECUTABLE NAMES krb5-config )
+    if( NOT KRB5_CONFIG_EXECUTABLE )
+      tde_message_fatal( "krb5 library is required but was not found on your system" )
+    endif( )
+  endif( )
+
+  execute_process(
+    COMMAND ${KRB5_CONFIG_EXECUTABLE} --libs
+    OUTPUT_VARIABLE KRB5_LIBRARIES
+    ERROR_VARIABLE KRB5_LIBRARIES
+  )
+  execute_process(
+    COMMAND ${KRB5_CONFIG_EXECUTABLE} --cflags
+    OUTPUT_VARIABLE KRB5_INCLUDE_DIRS
+    ERROR_VARIABLE KRB5_INCLUDE_DIRS
+  )
+  if( NOT "${KRB5_LIBRARIES}" STREQUAL "" )
+    set( KRB5_FOUND 1 )
+  endif( )
+endif( )

config.h.cmake

@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@

po/CMakeLists.txt

@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+    tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )
+endif( )

src/CMakeLists.txt

@@ -0,0 +1,53 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${TDE_INCLUDE_DIR}/tde
+  ${KRB5_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### kerberostray (executable)
+
+tde_add_executable( ${PROJECT_NAME} AUTOMOC
+
+  SOURCES
+        configdlgbase.ui
+        main.cpp
+        toplevel.cpp
+        configdlg.cpp
+  LINK
+     tdecore-shared
+     tdeui-shared
+     tdeio-shared
+     ${LIBTDELDAP_LIBRARIES}
+     ${KRB5_LIBRARIES}
+ 
+  DESTINATION ${BIN_INSTALL_DIR}
+)
+
+
+##### icons
+
+tde_install_icons( ${PROJECT_NAME} )
+tde_install_icons( DESTINATION ${DATA_INSTALL_DIR}/${PROJECT_NAME}/icons )
+
+
+##### other data
+
+install(
+    FILES ${PROJECT_NAME}.desktop
+    DESTINATION ${XDG_APPS_INSTALL_DIR}
+)
+
+install(
+    FILES ${PROJECT_NAME}.desktop
+    DESTINATION ${AUTOSTART_INSTALL_DIR}
+)